[XoD174]

Just got this macros on easyuo.com macros collection and it works really better than Razor peacemaking macros from IN Patcher! You don't need a horse or any other creature anymore! Just put instrument in your backpack and start macros!

Note: if your skill musicianship lower than 80.0 it will train musics to 80.0 first. I think it useless here but i already have GM musics so i leaved it as is If you haven't have 80.0 musicianship you can edit 23 string of this script before start using script.

Code:

;***************************************************************************************
; Script Name: Paladin's PeaceMaker Trainer
; Author: Paladin
; Version: 2.0.0b - Last Updated 11/10/06
; Original Script Relase : 9/26/05
; Client Tested with: 5.0.1j
; EUO version tested with: 1.5 - test Version 69
; Shard OSI / FreeShards : Tested on FS Alexandria - Should work on OSI
; Global Variables Used: none
; Purpose: Raise your Peacemaking skill by Targeting yourself! Suggested use on a Boat!
;  * if Musicianship is below 80 it will just gain music till 80 then do Peacemaking
;***************************************************************************************

set %instruments QRF_NRF_MQF_PRF_LQF_OQF_QRF_PGP
set %StartTime #scnt
;***************************************************************************************

_Start:

chooseskill musi
set %music #skill
event skillLock musi up
if %music < 800
{
set %startingskill #skill
set %currentskill #skill
gosub skillmenu
gosub music
}

chooseskill peac
set %startingskill #skill
set %currentskill #skill
event skillLock peac up  


event macro 8 3
wait 20

gosub skillmenu
gosub PaladinScriptTimer 95 110 115 110
gosub findinstrument

_Main:

gosub PaladinScriptTimer 95 110 115 110
gosub checkcap
gosub peacemake

goto _Main

;=======================================================================================

sub checkcap

chooseskill peac
if #skill = #skillcap
{
menu hide
display ok Finished! You've hit your Peacemaking Cap! Congrats!
halt
}

return

;=======================================================================================

sub peacemake

event macro 13 9
wait 10

scanjournal 1
if shall_you_play in #journal
gosub findinstrument

if #targCurs = 1
{
event macro 23 0
gosub checkskill peac
gosub PaladinScriptTimer 95 110 115 110
menu delete _curstatus
menu text _curstatus 55 80 PeaceMake Skill wait..
wait 9s
}

return

;=======================================================================================

sub findinstrument

set %dots .
set %_dots .

menu delete _curstatus
menu text _curstatus 55 80 Finding Instrument
menu delete _dots

for %i 1 10
{
menu text _dots 165 80 %_dots
wait 4
set %_dots %_dots , %dots
}

if #targCurs = 1
key esc

menu delete _dots

finditem %instruments C_ , #backpackid
if #findkind <> -1
{
menu delete _curstatus
menu text _curstatus 55 80 Instrument found!!
set #lobjectid #findid
wait 20
event macro 17 0
menu delete _curstatus
menu text _curstatus 55 80 Instrument played - waiting..
wait 7s
deletejournal
gosub PaladinScriptTimer 95 110 115 110
return
}

else
{
menu delete _dots
wait 10
key Esc
menu hide
display ok Out of Instruments! Halting!
halt
}

;=======================================================================================

sub music

_musictraining:

gosub PaladinScriptTimer 95 110 115 110

gosub playmusic
chooseskill musi
if #skill >= 800
{
menu hide
menu clear
wait 5
goto _Start
}

else
goto _musictraining

;=======================================================================================

sub playmusic

finditem %instruments C_ , #backpackid
if #findkind <> -1
{
set #lobjectid #findid
wait 10
event macro 17 0
gosub checkskill musi
gosub PaladinScriptTimer 95 110 115 110
menu delete _curstatus
menu text _curstatus 55 80 Instrument played - waiting..
wait 7s
return
}

else
{
wait 1s
menu hide
display Out of Instruments! Halting!
halt
}


;=======================================================================================

sub checkskill

wait 1s
chooseskill %1
if #skill > %currentskill
{
set %currentskill #skill
str len %currentskill
str ins %currentskill #dot #strRes
menu delete _currentskill
menu text _currentskill 90 20 #strRes
set %skillgains %currentskill - %startingskill
str len %skillgains
str ins %skillgains #dot #strRes
menu delete _skillgains
menu text _skillgains 90 50 #strRes
}

gosub PaladinScriptTimer 95 110 115 110
return

;=======================================================================================

sub skillmenu

menu clear
menu window title Paladin's PeaceMaker Trainer
menu window size 275 140
menu window color Black
menu Font Name Times New Roman
menu font bgcolor Black
menu font size 10
menu font color Yellow
menu text curskill 10 20 Current skill:
menu text totgains 10 50 Total gains:
menu text curstatus 10 80 Status:
menu text time 10 110 Time Running:
menu font color Lime

set %currentskill #skill
str len %currentskill
str ins %currentskill #dot #strRes
menu delete _currentskill
menu text _currentskill 90 20 #strRes
set %skillgains %currentskill - %startingskill
str len %skillgains
str ins %skillgains #dot #strRes
menu delete _skillgains
menu text _skillgains 90 50 #strRes

menu show
return


;==========================================================================
; Please keep this header with the sub if you use it
;Name: PaladinScriptTimer Sub
;author: paladin
;Version 1.0 1
;Date released: 3/27/06
;Purpose: Sub that displays time in hours and minutes since
;         script started
;         Updates the displayed timer when called
;
; parameters : %1 menuposx for Hour display
;            : %2 menuposy for Hour display
;            : %3 menuposx for Minute display
;            : %4 menuposy for Minute display
;
; returns nothing
;
;==========================================================================

sub PaladinScriptTimer

set %TimeSpent #scnt - %StartTime

set %Hours ( %TimeSpent / 3600 )
set %Mins  ( %TimeSpent / 60 ) - ( %Hours * 60 )

if %PrevHours <> %Hours
{
  set %PrevHours %Hours
  menu delete _Hours
  menu text _Hours %1 %2 %Hours h
}
if %PrevMins <> %Mins
{
  set %PrevMins %Mins
  menu delete _Mins
  menu text _Mins %3 %4 %Mins m
}

return

;==========================================================================

P.S.: Shade, pleeease fix Google +1 button at the bottom of each forum page!

[Raziel_]

Having gm musicianship is importante because you will fail less when you try to peace, the point is the delay to use another skill if you fail the attempt to peace is much longer than when you peace!
I used razor to gm my peacemaking and it was pretty fast, i had no pauses on my macro and the wait for target i set to 1... i had spams on my screen saying i had to wait to perform another action... but since i was afk it didnt bother me

[Emerald]

[COLOR="green"]This worked great for me...

:evil:[/COLOR]

[Atlas]

you didnt need another target with razor anyway =p
Here's my old peacing macro:

Use Skill Peacemaking
Wait for Target
Exec: Target Self
Pause: 5.000
(loop)

lol
And for provo, just use the Sparring partners in the merc camp instead of the horses...way easier because the targets never go away/change and never attack one another