[Catalyst]

So I left a provo macro on overnight and had my STR checked down and INT checked up to re-order my stats a bit.

I came back and my INT was 120 like I expected but my STR was down to 50. According to the stat/skill chart at http://www.uoguide.com/Stats neither Musicianship or Provocation effects STR. So once my INT got to 120 shouldn't my STR have stopped decreasing? It's a little annoying since I have to go get my stats back up but I was wondering if this may be a bug or something?

[Cana]

Found some old EUO macro for stats. It's not made for IN but you can use the part of it adjusting your stat locks. You set the values in variables and it'll automatically adjust stat locks up/down/locked when needed.

Code:

; OzStats
; Stat macro for doing STR, DEX and INT with Arms Lore and Item ID.
; Seesaw macro up to 10 points. Good for STR and INT, not so good for dex.

set %targetSTR 95
set %targetDEX 20
set %targetINT 110

set #lpc 1000
set %skill 1

Exevent SkillLock item down
Exevent SkillLock arms up

set %target LJGLDPD

while ( #STR <> %targetSTR || #DEX <> %targetDEX || #INT <> %targetINT )
{
  gosub AdjustStatLocks
  ;gosub SpamSkill
}
event sysmessage ++ Stats are ready!
halt

sub AdjustStatLocks
  if ( #STR = %targetSTR )
    exevent StatLock str locked
  if ( #STR < %targetSTR )
    exevent StatLock str up
  if ( #STR > %targetSTR )
    exevent StatLock str down
    
  if ( #DEX = %targetDEX )
    exevent StatLock dex locked
  if ( #DEX < %targetDEX )
    exevent StatLock dex up
  if ( #DEX > %targetDEX )
    exevent StatLock dex down
    
  if ( #INT = %targetINT )
    exevent StatLock int locked
  if ( #INT < %targetINT )
    exevent StatLock int up
  if ( #INT > %targetINT )
    exevent StatLock int down
return

sub SpamSkill
  if ( %skill = 1 )
  {
    chooseskill arms
    if ( #skill >= 100 )
    {
       Exevent SkillLock arms down
       Exevent SkillLock item up
       set %skill 2
    }
    else
    {
      set #LTARGETID %target
      event macro 13 4
      target 1s
      event Macro 22 0
    }
  }
  if ( %skill = 2 )
  {
    chooseskill item
    if ( #skill >= 100 )
    {
       Exevent SkillLock item down
       Exevent SkillLock arms up
       set %skill 1
    }
    else
    {
      set #LTARGETID %target
      event macro 13 3
      target 1s
      event Macro 22 0
    }
  }
return

I commented out the part about using skills. Run it along with any macro you use to gain stats.