Imagine Nation Forums
EUO: Combats (Merc camp) - Printable Version

+- Imagine Nation Forums (https://in-uo.net/forums)
+-- Forum: Imagine Nation archive (https://in-uo.net/forums/forumdisplay.php?fid=6)
+--- Forum: Player Guides (https://in-uo.net/forums/forumdisplay.php?fid=29)
+--- Thread: EUO: Combats (Merc camp) (/showthread.php?tid=384)


EUO: Combats (Merc camp) - Cana - 06-19-2011

Instructions are included in the macro script. Paste the code below into EUO, read the instructions and make changes if needed and play the macro.

Code:
; Combat training macro at IN Mercenary Camp
;
; This macro will train your swords, mace, parry, tactics and healing. It is
; set to work with southern water trough in the camp but that can be changed
; with %water variable. As it is, macro works with training swords and training
; maces. You can add your own weapons in to the %weapon variable if you wish.
;
; How to set up the macro:
; ========================
; Put on some armor, grab some heater shields and training weapons of choise.
; You might need to set %target to your desired sparring partner. You can do
; this by bringing up a target icon with any item (I use scissors) and target
; your desired target. You'll see the value in the section on the right
; (under Last Action -> #LTARGETID). Put that value into %target variable
; (instead of FIB what it currently is). If you wish, you can adjust the
; %HPtreshold value. If your hitpoints go under this value your character will
; heal using bandages until above the treshold and then go back to attacking.

set %target FIB
set %HPtreshold 80
set %water WQHUCND
set %weapon BPH_QOH

if ! ( G in #CHARSTATUS )
  gosub CombatMode

while ( #TRUE )
{
  set #LTARGETID %target
  gosub AttackLast
  if ( #HITS < %HPtreshold )
    gosub HealMe
  finditem ZLF C
  if #FINDCNT < 1
  {
    finditem AMF C
    if #FINDCNT > 0
    {
      set #LOBJECTID #FINDID
      set #LTARGETID %water
      event macro 17 0
      target 1s
      event Macro 22 0
      wait 10
    }
  }
}
halt

sub AttackLast
  event macro 27 0
return

sub CombatMode
  event macro 6 0
  wait 1s
return

sub HealMe
  finditem ZLF C
  if #FINDCNT > 0
  {
    set #LOBJECTID #FINDID
    event macro 17 0
    target 1s
    event Macro 23 0
    
    finditem %weapon C
    if #FINDCNT > 0
    {
      set #LOBJECTID #FINDID
      set #LTARGETID %target
      event macro 17 0
      target 1s
      event Macro 22 0
    }
    finditem CIK C
    if #FINDCNT > 0
    {
      set #LOBJECTID #FINDID
      event macro 17 0
    }
    
    wait 53
  }
  gosub AttackLast
return